VintaSoft Twain .NET SDK v10.3
In This Topic
    How to detect the end of batch job?
    In This Topic

    Example: Here is an example that shows how to detect job separators while scanning.

    ' The project, which uses this code, must have references to the following assemblies:
    ' - Vintasoft.Twain
    
    Imports System.Windows.Forms
    Imports Vintasoft.Twain
    
    Partial Public Class How_to_detect_the_end_of_batch_job
        Inherits Form
    
        ''' <summary>
        ''' TWAIN device manager.
        ''' </summary>
        ''' <remarks></remarks>
        Private _deviceManager As DeviceManager
    
        ''' <summary>
        ''' Job counter.
        ''' </summary>
        ''' <remarks></remarks>
        Private _jobCounter As Integer = -1
    
    
    
        Public Sub New()
            InitializeComponent()
    
            ' create and open device manager
            _deviceManager = New DeviceManager(Me)
            _deviceManager.Open()
        End Sub
    
    
    
        ''' <summary>
        ''' Acquires images asynchronously.
        ''' </summary>
        Public Sub AcquireImagesAsynchronously()
            Try
                ' get reference to the default device
                Dim device1 As Device = _deviceManager.DefaultDevice
    
                ' subscribe to the device events
                AddHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
                AddHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
                AddHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
                AddHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)
    
                ' set scanning settings
                device1.TransferMode = TransferMode.Memory
                device1.ShowUI = True
    
                ' open the device
                device1.Open()
                ' specify that job separator must be searched and scanned
                device1.JobControl = JobControl.DetectAndIncludeJobSeparatorAndContinueScanning
                ' increment job count
                _jobCounter = _jobCounter + 1
    
                ' acquire images asynchronously
                device1.Acquire()
            Catch ex As TwainException
                MessageBox.Show(ex.Message)
            End Try
        End Sub
    
        ''' <summary>
        ''' Image is acquired.
        ''' </summary>
        Private Sub device_ImageAcquired(ByVal sender As Object, ByVal e As Vintasoft.Twain.ImageAcquiredEventArgs)
            Dim device As Device = DirectCast(sender, Device)
            ' if job separator is detected
            If device.EndOfJob Then
                ' increment job count and do not save the job separator image
                _jobCounter = _jobCounter + 1
            Else
                ' if job separator is NOT detected
                ' add image to the multipage TIFF file for current job
                e.Image.Save(String.Format("d:\job{0}.tif", _jobCounter))
            End If
    
            ' dispose the acquired image
            e.Image.Dispose()
        End Sub
    
        ''' <summary>
        ''' Scan is canceled.
        ''' </summary>
        Private Sub device_ScanCanceled(ByVal sender As Object, ByVal e As EventArgs)
            MessageBox.Show("Scan is canceled.")
        End Sub
    
        ''' <summary>
        ''' Scan is failed.
        ''' </summary>
        Private Sub device_ScanFailed(ByVal sender As Object, ByVal e As Vintasoft.Twain.ScanFailedEventArgs)
            MessageBox.Show("Scan is failed: " + Convert.ToString(e.ErrorString))
        End Sub
    
        ''' <summary>
        ''' Scan is finished.
        ''' </summary>
        Private Sub device_ScanFinished(ByVal sender As Object, ByVal e As EventArgs)
            Dim device1 As Device = DirectCast(sender, Device)
    
            ' unsubscribe from device events
            RemoveHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
            RemoveHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
            RemoveHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
            RemoveHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)
    
            ' if device is not closed
            If device1.State <> DeviceState.Closed Then
                ' close the device
                device1.Close()
            End If
    
            MessageBox.Show("Scan is finished.")
        End Sub
    
    End Class
                  
    
    // The project, which uses this code, must have references to the following assemblies:
    // - Vintasoft.Twain
    
    using System;
    using System.Windows.Forms;
    using Vintasoft.Twain;
    
    namespace TwainExamples_CSharp
    {
        public partial class How_to_detect_the_end_of_batch_job : Form
        {
    
            /// <summary>
            /// TWAIN device manager.
            /// </summary>
            DeviceManager _deviceManager;
    
            /// <summary>
            /// Job counter.
            /// </summary>
            int _jobCounter = -1; 
    
    
    
            public How_to_detect_the_end_of_batch_job()
            {
                InitializeComponent();
    
                // create and open device manager
                _deviceManager = new DeviceManager(this);
                _deviceManager.Open();
            }
    
    
    
            /// <summary>
            /// Acquire images asynchronously.
            /// </summary>
            public void AcquireImagesAsynchronously()
            {
                try
                {
                    // get reference to the default device
                    Device device = _deviceManager.DefaultDevice;
    
                    // subscribe to the device events
                    device.ImageAcquired += new EventHandler<ImageAcquiredEventArgs>(device_ImageAcquired);
                    device.ScanCanceled += new EventHandler(device_ScanCanceled);
                    device.ScanFailed += new EventHandler<ScanFailedEventArgs>(device_ScanFailed);
                    device.ScanFinished += new EventHandler(device_ScanFinished);
    
                    // set scanning settings
                    device.TransferMode = TransferMode.Memory;
                    device.ShowUI = true;
    
                    // open the device
                    device.Open();
                    // specify that job separator must be searched and scanned
                    device.JobControl = JobControl.DetectAndIncludeJobSeparatorAndContinueScanning;
                    // increment job count
                    _jobCounter = _jobCounter + 1; 
    
                    // acquire images asynchronously
                    device.Acquire();
                }
                catch (TwainException ex)
                {
                    MessageBox.Show(ex.Message);
                }
            }
    
            /// <summary>
            /// Image is acquired.
            /// </summary>
            private void device_ImageAcquired(object sender, Vintasoft.Twain.ImageAcquiredEventArgs e)
            {
                Device device = (Device)sender;
                // if job separator is detected
                if (device.EndOfJob)
                    // increment job count and do not save the job separator image
                    _jobCounter = _jobCounter + 1;
                // if job separator is NOT detected
                else
                    // add image to the multipage TIFF file for current job
                    e.Image.Save(string.Format(@"d:\job{0}.tif", _jobCounter));
    
                // dispose the acquired image
                e.Image.Dispose();
            }
    
            /// <summary>
            /// Scan is canceled.
            /// </summary>
            private void device_ScanCanceled(object sender, EventArgs e)
            {
                MessageBox.Show("Scan is canceled.");
            }
    
            /// <summary>
            /// Scan is failed.
            /// </summary>
            private void device_ScanFailed(object sender, Vintasoft.Twain.ScanFailedEventArgs e)
            {
                MessageBox.Show("Scan is failed: " + e.ErrorString);
            }
    
            /// <summary>
            /// Scan is finished.
            /// </summary>
            void device_ScanFinished(object sender, EventArgs e)
            {
                Device device = (Device)sender;
    
                // unsubscribe from device events
                device.ImageAcquired -= new EventHandler<ImageAcquiredEventArgs>(device_ImageAcquired);
                device.ScanCanceled -= new EventHandler(device_ScanCanceled);
                device.ScanFailed -= new EventHandler<ScanFailedEventArgs>(device_ScanFailed);
                device.ScanFinished -= new EventHandler(device_ScanFinished);
    
                // if device is not closed
                if (device.State != DeviceState.Closed)
                    // close the device
                    device.Close();
    
                MessageBox.Show("Scan is finished.");
            }
    
        }
    }