How to save acquired image as JPEG file?

In This Topic

You can acquire image from scanner and save it as JPEG file by 3 ways:

1. Using Native or Memory transfer mode

This method works with any scanners.
Image is encoded using internal encoder of SDK.
JPEG quality can be set using the TwainJpegEncoderSettings.JpegQuality property.
Image is saved as JPEG file using the AcquiredImage.Save method.

Example: Here is an example that shows how to acquire image and save image as JPEG file using JPEG encoder of SDK.

VB.NET

Imports System.Windows.Forms
Imports Vintasoft.Twain
Imports Vintasoft.Twain.ImageEncoders

''' <summary>
''' Class allows to scan non compressed image and save image to a disk as JPEG file.
''' </summary>
Partial Public Class How_to_scan_non_compressed_image_and_save_image_to_disk_as_Jpeg_file
    Inherits Form

    ''' <summary>
    ''' TWAIN device manager.
    ''' </summary>
    Private _deviceManager As DeviceManager



    Public Sub New()
        InitializeComponent()

        ' create and open device manager
        _deviceManager = New DeviceManager(Me)
        _deviceManager.Open()
    End Sub



    ''' <summary>
    ''' Acquire images asynchronously.
    ''' </summary>
    Public Sub AcquireImagesAsynchronously()
        Try
            ' get reference to the default device
            Dim device1 As Device = _deviceManager.OpenedDevice

            ' subscribe to the device events
            AddHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
            AddHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
            AddHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
            AddHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)

            ' disable UI
            device1.ShowUI = False

            ' set Memory (or Native) transfer mode
            device1.TransferMode = TransferMode.Memory

            ' acquire images asynchronously
            device1.Acquire()
        Catch ex As TwainException
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    ''' <summary>
    ''' Image is acquired.
    ''' </summary>
    Private Sub device_ImageAcquired(ByVal sender As Object, ByVal e As Vintasoft.Twain.ImageAcquiredEventArgs)
        Dim jpegCodecParams As New TwainJpegEncoderSettings()
        jpegCodecParams.JpegQuality = 50

        ' save acquired image to disk using JPEG encoder of SDK
        e.Image.Save("test.jpg", jpegCodecParams)

        ' dispose the acquired image
        e.Image.Dispose()
    End Sub

    ''' <summary>
    ''' Scan is canceled.
    ''' </summary>
    Private Sub device_ScanCanceled(ByVal sender As Object, ByVal e As EventArgs)
        MessageBox.Show("Scan is canceled.")
    End Sub

    ''' <summary>
    ''' Scan is failed.
    ''' </summary>
    Private Sub device_ScanFailed(ByVal sender As Object, ByVal e As Vintasoft.Twain.ScanFailedEventArgs)
        MessageBox.Show("Scan is failed: " + Convert.ToString(e.ErrorString))
    End Sub

    ''' <summary>
    ''' Scan is finished.
    ''' </summary>
    Private Sub device_ScanFinished(ByVal sender As Object, ByVal e As EventArgs)
        Dim device1 As Device = DirectCast(sender, Device)

        ' unsubscribe from device events
        RemoveHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
        RemoveHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
        RemoveHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
        RemoveHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)

        ' if device is not closed
        If device1.State <> DeviceState.Closed Then
            ' close the device
            device1.Close()
        End If

        MessageBox.Show("Scan is finished.")
    End Sub

End Class

using System;
using System.Windows.Forms;
using Vintasoft.Twain;
using Vintasoft.Twain.ImageEncoders;

namespace TwainExamples_CSharp
{
    /// <summary>
    /// Class allows to scan non compressed image and save image to a disk as JPEG file.
    /// </summary>
    public partial class How_to_scan_non_compressed_image_and_save_image_to_disk_as_Jpeg_file : Form
    {

        /// <summary>
        /// TWAIN device manager.
        /// </summary>
        DeviceManager _deviceManager;



        public How_to_scan_non_compressed_image_and_save_image_to_disk_as_Jpeg_file()
        {
            InitializeComponent();

            // create and open device manager
            _deviceManager = new DeviceManager(this);
            _deviceManager.Open();
        }



        /// <summary>
        /// Acquire images asynchronously.
        /// </summary>
        public void AcquireImagesAsynchronously()
        {
            try
            {
                // get reference to the default device
                Device device = _deviceManager.OpenedDevice;

                // subscribe to the device events
                device.ImageAcquired += new EventHandler(device_ImageAcquired);
                device.ScanCanceled += new EventHandler(device_ScanCanceled);
                device.ScanFailed += new EventHandler(device_ScanFailed);
                device.ScanFinished += new EventHandler(device_ScanFinished);

                // disable UI
                device.ShowUI = false;

                // set Memory (or Native) transfer mode
                device.TransferMode = TransferMode.Memory;

                // acquire images asynchronously
                device.Acquire();
            }
            catch (TwainException ex)
            {
                MessageBox.Show(ex.Message);
            }
        }

        /// <summary>
        /// Image is acquired.
        /// </summary>
        private void device_ImageAcquired(object sender, Vintasoft.Twain.ImageAcquiredEventArgs e)
        {
            TwainJpegEncoderSettings jpegCodecParams = new TwainJpegEncoderSettings();
            jpegCodecParams.JpegQuality = 50;

            // save acquired image to disk using JPEG encoder of SDK
            e.Image.Save("test.jpg", jpegCodecParams);

            // dispose the acquired image
            e.Image.Dispose();
        }

        /// <summary>
        /// Scan is canceled.
        /// </summary>
        private void device_ScanCanceled(object sender, EventArgs e)
        {
            MessageBox.Show("Scan is canceled.");
        }

        /// <summary>
        /// Scan is failed.
        /// </summary>
        private void device_ScanFailed(object sender, Vintasoft.Twain.ScanFailedEventArgs e)
        {
            MessageBox.Show("Scan is failed: " + e.ErrorString);
        }

        /// <summary>
        /// Scan is finished.
        /// </summary>
        void device_ScanFinished(object sender, EventArgs e)
        {
            Device device = (Device)sender;

            // unsubscribe from device events
            device.ImageAcquired -= new EventHandler(device_ImageAcquired);
            device.ScanCanceled -= new EventHandler(device_ScanCanceled);
            device.ScanFailed -= new EventHandler(device_ScanFailed);
            device.ScanFinished -= new EventHandler(device_ScanFinished);

            // if device is not closed
            if (device.State != DeviceState.Closed)
                // close the device
                device.Close();

            MessageBox.Show("Scan is finished.");
        }

    }
}

2. Using File transfer mode

TWAIN driver must have built-in JPEG encoder - you can check this with the Device.GetSupportedImageFileFormats method.
TWAIN driver encodes acquired image and saves directly to disk.
JPEG compression can be set using the Device.FileFormat property.
Filename of JPEG file can be set using the Device.FileName property.
Quality of JPEG file can be set using the Device.FileJpegQuality property.

Example: Here is an example that shows how to save acquired image directly to disk as JPEG file.

VB.NET

Imports System.Windows.Forms
Imports Vintasoft.Twain

''' <summary>
''' Class allows to scan and save image directly to disk as JPEG file.
''' </summary>
Partial Public Class How_to_scan_and_save_compressed_image_directly_to_disk_as_Jpeg_file
    Inherits Form

    ''' <summary>
    ''' TWAIN device manager.
    ''' </summary>
    Private _deviceManager As DeviceManager

    ''' <summary>
    ''' Image count.
    ''' </summary>
    Private _imageCount As Integer = 0



    Public Sub New()
        InitializeComponent()

        ' create and open device manager
        _deviceManager = New DeviceManager(Me)
        _deviceManager.Open()
    End Sub



    ''' <summary>
    ''' Acquire images asynchronously.
    ''' </summary>
    Public Sub AcquireImagesAsynchronously()
        Try
            ' get reference to the default device
            Dim device1 As Device = _deviceManager.DefaultDevice

            ' open the device
            device1.Open()

            ' check if device driver can save image to disk as JPEG files
            Dim supportedImageFileFormats As TwainImageFileFormat() = device1.GetSupportedImageFileFormats()
            Dim isJpegFileFormatSupported As Boolean = False
            For i As Integer = 0 To supportedImageFileFormats.Length - 1
                If supportedImageFileFormats(i) = TwainImageFileFormat.Jpeg Then
                    isJpegFileFormatSupported = True
                    Exit For
                End If
            Next
            '
            If Not isJpegFileFormatSupported Then
                ' close the device
                device1.Close()
                MessageBox.Show("Device cannot save acquired image directly to disk as JPEG image.")
                Return
            End If


            ' subscribe to the device events
            AddHandler device1.ImageAcquiring, New EventHandler(Of ImageAcquiringEventArgs)(AddressOf device_ImageAcquiring)
            AddHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
            AddHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
            AddHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
            AddHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)

            ' disable UI
            device1.ShowUI = False

            ' set the File transfer mode
            device1.TransferMode = TransferMode.File
            ' save images as JPEG files
            device1.FileFormat = TwainImageFileFormat.Jpeg
            ' set JPEG quality
            device1.FileJpegQuality = 50

            ' acquire images asynchronously
            device1.Acquire()
        Catch ex As TwainException
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    ''' <summary>
    ''' Image is acquiring.
    ''' </summary>
    Private Sub device_ImageAcquiring(ByVal sender As Object, ByVal e As ImageAcquiringEventArgs)
        ' set the filename for image
        e.Filename = String.Format("test{0}.jpg", _imageCount)
    End Sub

    ''' <summary>
    ''' Image is acquired.
    ''' </summary>
    Private Sub device_ImageAcquired(ByVal sender As Object, ByVal e As Vintasoft.Twain.ImageAcquiredEventArgs)
        ' image is already saved to disk as JPEG file

        ' increment image count
        _imageCount = _imageCount + 1
    End Sub

    ''' <summary>
    ''' Scan is canceled.
    ''' </summary>
    Private Sub device_ScanCanceled(ByVal sender As Object, ByVal e As EventArgs)
        MessageBox.Show("Scan is canceled.")
    End Sub

    ''' <summary>
    ''' Scan is failed.
    ''' </summary>
    Private Sub device_ScanFailed(ByVal sender As Object, ByVal e As Vintasoft.Twain.ScanFailedEventArgs)
        MessageBox.Show("Scan is failed: " + Convert.ToString(e.ErrorString))
    End Sub

    ''' <summary>
    ''' Scan is finished.
    ''' </summary>
    Private Sub device_ScanFinished(ByVal sender As Object, ByVal e As EventArgs)
        Dim device1 As Device = DirectCast(sender, Device)

        ' unsubscribe from device events
        RemoveHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
        RemoveHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
        RemoveHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
        RemoveHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)

        ' if device is not closed
        If device1.State <> DeviceState.Closed Then
            ' close the device
            device1.Close()
        End If

        MessageBox.Show("Scan is finished.")
    End Sub

End Class

using System;
using System.Windows.Forms;
using Vintasoft.Twain;

namespace TwainExamples_CSharp
{
    /// <summary>
    /// Class allows to scan and save image directly to disk as JPEG file.
    /// </summary>
    public partial class How_to_scan_and_save_compressed_image_directly_to_disk_as_Jpeg_file : Form
    {

        /// <summary>
        /// TWAIN device manager.
        /// </summary>
        DeviceManager _deviceManager;

        /// <summary>
        /// Image count.
        /// </summary>
        int _imageCount = 0;



        public How_to_scan_and_save_compressed_image_directly_to_disk_as_Jpeg_file()
        {
            InitializeComponent();

            // create and open device manager
            _deviceManager = new DeviceManager(this);
            _deviceManager.Open();
        }



        /// <summary>
        /// Acquire images asynchronously.
        /// </summary>
        public void AcquireImagesAsynchronously()
        {
            try
            {
                // get reference to the default device
                Device device = _deviceManager.DefaultDevice;

                // open the device
                device.Open();

                // check if device driver can save image to disk as JPEG files
                TwainImageFileFormat[] supportedImageFileFormats = device.GetSupportedImageFileFormats();
                bool isJpegFileFormatSupported = false;
                for (int i = 0; i < supportedImageFileFormats.Length; i++)
                {
                    if (supportedImageFileFormats[i] == TwainImageFileFormat.Jpeg)
                    {
                        isJpegFileFormatSupported = true;
                        break;
                    }
                }
                //
                if (!isJpegFileFormatSupported)
                {
                    // close the device
                    device.Close();
                    MessageBox.Show("Device cannot save acquired image directly to disk as JPEG image.");
                    return;
                }


                // subscribe to the device events
                device.ImageAcquiring += new EventHandler(device_ImageAcquiring);
                device.ImageAcquired += new EventHandler(device_ImageAcquired);
                device.ScanCanceled += new EventHandler(device_ScanCanceled);
                device.ScanFailed += new EventHandler(device_ScanFailed);
                device.ScanFinished += new EventHandler(device_ScanFinished);

                // disable UI
                device.ShowUI = false;

                // set the File transfer mode
                device.TransferMode = TransferMode.File;
                // save images as JPEG files
                device.FileFormat = TwainImageFileFormat.Jpeg;
                // set JPEG quality
                device.FileJpegQuality = 50;

                // acquire images asynchronously
                device.Acquire();
            }
            catch (TwainException ex)
            {
                MessageBox.Show(ex.Message);
            }
        }

        /// <summary>
        /// Image is acquiring.
        /// </summary>
        private void device_ImageAcquiring(object sender, ImageAcquiringEventArgs e)
        {
            // set the filename for image
            e.Filename = string.Format("test{0}.jpg", _imageCount);
        }

        /// <summary>
        /// Image is acquired.
        /// </summary>
        private void device_ImageAcquired(object sender, Vintasoft.Twain.ImageAcquiredEventArgs e)
        {
            // image is already saved to disk as JPEG file

            // increment image count
            _imageCount = _imageCount + 1;
        }

        /// <summary>
        /// Scan is canceled.
        /// </summary>
        private void device_ScanCanceled(object sender, EventArgs e)
        {
            MessageBox.Show("Scan is canceled.");
        }

        /// <summary>
        /// Scan is failed.
        /// </summary>
        private void device_ScanFailed(object sender, Vintasoft.Twain.ScanFailedEventArgs e)
        {
            MessageBox.Show("Scan is failed: " + e.ErrorString);
        }

        /// <summary>
        /// Scan is finished.
        /// </summary>
        void device_ScanFinished(object sender, EventArgs e)
        {
            Device device = (Device)sender;

            // unsubscribe from device events
            device.ImageAcquired -= new EventHandler(device_ImageAcquired);
            device.ScanCanceled -= new EventHandler(device_ScanCanceled);
            device.ScanFailed -= new EventHandler(device_ScanFailed);
            device.ScanFinished -= new EventHandler(device_ScanFinished);

            // if device is not closed
            if (device.State != DeviceState.Closed)
                // close the device
                device.Close();

            MessageBox.Show("Scan is finished.");
        }

    }
}

3. Using Memory transfer mode

TWAIN driver must have built-in JPEG encoder - you can check this with the Device.GetSupportedImageCompressions method.
TWAIN driver returns acquired image as JPEG stream.
JPEG compression can be set using the Device.ImageCompression property.
Quality of JPEG file can be set using the DeviceCapabilityId.IJpegQuality capability.

Example: Here is an example that shows how to acquire image as JPEG stream and save image to disk.

VB.NET

Imports System.Windows.Forms
Imports Vintasoft.Twain

''' <summary>
''' Class allows to scan compressed image and save image to a disk as JPEG file.
''' </summary>
Partial Public Class How_to_scan_compressed_image_and_save_image_to_disk_as_Jpeg_file
    Inherits Form

    ''' <summary>
    ''' TWAIN device manager.
    ''' </summary>
    Private _deviceManager As DeviceManager



    Public Sub New()
        InitializeComponent()

        ' create and open device manager
        _deviceManager = New DeviceManager(Me)
        _deviceManager.Open()
    End Sub



    ''' <summary>
    ''' Acquire images asynchronously.
    ''' </summary>
    Public Sub AcquireImagesAsynchronously()
        Try
            ' get reference to the default device
            Dim device1 As Device = _deviceManager.DefaultDevice

            ' open the device
            device1.Open()

            ' check if device driver can return image data as JPEG stream
            Dim supportedImageCompressions As TwainImageCompression() = device1.GetSupportedImageCompressions()
            Dim isJpegCompressionSupported As Boolean = False
            For i As Integer = 0 To supportedImageCompressions.Length - 1
                If supportedImageCompressions(i) = TwainImageCompression.Jpeg Then
                    isJpegCompressionSupported = True
                    Exit For
                End If
            Next
            '
            If Not isJpegCompressionSupported Then
                ' close the device
                device1.Close()
                MessageBox.Show("Device driver cannot return image data as JPEG stream.")
                Return
            End If

            ' subscribe to the device events
            AddHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
            AddHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
            AddHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
            AddHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)

            ' disable UI
            device1.ShowUI = False

            ' set Memory transfer mode
            device1.TransferMode = TransferMode.Memory
            ' set JPEG compression for image data
            device1.ImageCompression = TwainImageCompression.Jpeg
            ' set JPEG quality
            Dim jpegQualityCap As DeviceCapability = device1.Capabilities.Find(DeviceCapabilityId.IJpegQuality)
            If jpegQualityCap IsNot Nothing Then
                jpegQualityCap.SetValue(CInt(50))
            End If

            ' acquire images asynchronously
            device1.Acquire()
        Catch ex As TwainException
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    ''' <summary>
    ''' Image is acquired.
    ''' </summary>
    Private Sub device_ImageAcquired(ByVal sender As Object, ByVal e As Vintasoft.Twain.ImageAcquiredEventArgs)
        ' save acquired image to disk, SDK will save JPEG stream received
        ' from device driver
        e.Image.Save("test.jpg")

        ' dispose the acquired image
        e.Image.Dispose()
    End Sub

    ''' <summary>
    ''' Scan is canceled.
    ''' </summary>
    Private Sub device_ScanCanceled(ByVal sender As Object, ByVal e As EventArgs)
        MessageBox.Show("Scan is canceled.")
    End Sub

    ''' <summary>
    ''' Scan is failed.
    ''' </summary>
    Private Sub device_ScanFailed(ByVal sender As Object, ByVal e As Vintasoft.Twain.ScanFailedEventArgs)
        MessageBox.Show("Scan is failed: " + Convert.ToString(e.ErrorString))
    End Sub

    ''' <summary>
    ''' Scan is finished.
    ''' </summary>
    Private Sub device_ScanFinished(ByVal sender As Object, ByVal e As EventArgs)
        Dim device1 As Device = DirectCast(sender, Device)

        ' unsubscribe from device events
        RemoveHandler device1.ImageAcquired, New EventHandler(Of ImageAcquiredEventArgs)(AddressOf device_ImageAcquired)
        RemoveHandler device1.ScanCanceled, New EventHandler(AddressOf device_ScanCanceled)
        RemoveHandler device1.ScanFailed, New EventHandler(Of ScanFailedEventArgs)(AddressOf device_ScanFailed)
        RemoveHandler device1.ScanFinished, New EventHandler(AddressOf device_ScanFinished)

        ' if device is not closed
        If device1.State <> DeviceState.Closed Then
            ' close the device
            device1.Close()
        End If

        MessageBox.Show("Scan is finished.")
    End Sub

End Class

using System;
using System.Windows.Forms;
using Vintasoft.Twain;

namespace TwainExamples_CSharp
{
    /// <summary>
    /// Class allows to scan compressed image and save image to a disk as JPEG file.
    /// </summary>
    public partial class How_to_scan_compressed_image_and_save_image_to_disk_as_Jpeg_file : Form
    {

        /// <summary>
        /// TWAIN device manager.
        /// </summary>
        DeviceManager _deviceManager;



        public How_to_scan_compressed_image_and_save_image_to_disk_as_Jpeg_file()
        {
            InitializeComponent();

            // create and open device manager
            _deviceManager = new DeviceManager(this);
            _deviceManager.Open();
        }



        /// <summary>
        /// Acquire images asynchronously.
        /// </summary>
        public void AcquireImagesAsynchronously()
        {
            try
            {
                // get reference to the default device
                Device device = _deviceManager.DefaultDevice;

                // open the device
                device.Open();

                // check if device driver can return image data as JPEG stream
                TwainImageCompression[] supportedImageCompressions = device.GetSupportedImageCompressions();
                bool isJpegCompressionSupported = false;
                for (int i = 0; i < supportedImageCompressions.Length; i++)
                {
                    if (supportedImageCompressions[i] == TwainImageCompression.Jpeg)
                    {
                        isJpegCompressionSupported = true;
                        break;
                    }
                }
                //
                if (!isJpegCompressionSupported)
                {
                    // close the device
                    device.Close();
                    MessageBox.Show("Device driver cannot return image data as JPEG stream.");
                    return;
                }

                // subscribe to the device events
                device.ImageAcquired += new EventHandler(device_ImageAcquired);
                device.ScanCanceled += new EventHandler(device_ScanCanceled);
                device.ScanFailed += new EventHandler(device_ScanFailed);
                device.ScanFinished += new EventHandler(device_ScanFinished);

                // disable UI
                device.ShowUI = false;

                // set Memory transfer mode
                device.TransferMode = TransferMode.Memory;
                // set JPEG compression for image data
                device.ImageCompression = TwainImageCompression.Jpeg;
                // set JPEG quality
                DeviceCapability jpegQualityCap = device.Capabilities.Find(DeviceCapabilityId.IJpegQuality);
                if (jpegQualityCap != null)
                    jpegQualityCap.SetValue((int)50);

                // acquire images asynchronously
                device.Acquire();
            }
            catch (TwainException ex)
            {
                MessageBox.Show(ex.Message);
            }
        }

        /// <summary>
        /// Image is acquired.
        /// </summary>
        private void device_ImageAcquired(object sender, Vintasoft.Twain.ImageAcquiredEventArgs e)
        {
            // save acquired image to disk, SDK will save JPEG stream received
            // from device driver
            e.Image.Save("test.jpg");

            // dispose the acquired image
            e.Image.Dispose();
        }

        /// <summary>
        /// Scan is canceled.
        /// </summary>
        private void device_ScanCanceled(object sender, EventArgs e)
        {
            MessageBox.Show("Scan is canceled.");
        }

        /// <summary>
        /// Scan is failed.
        /// </summary>
        private void device_ScanFailed(object sender, Vintasoft.Twain.ScanFailedEventArgs e)
        {
            MessageBox.Show("Scan is failed: " + e.ErrorString);
        }

        /// <summary>
        /// Scan is finished.
        /// </summary>
        void device_ScanFinished(object sender, EventArgs e)
        {
            Device device = (Device)sender;

            // unsubscribe from device events
            device.ImageAcquired -= new EventHandler(device_ImageAcquired);
            device.ScanCanceled -= new EventHandler(device_ScanCanceled);
            device.ScanFailed -= new EventHandler(device_ScanFailed);
            device.ScanFinished -= new EventHandler(device_ScanFinished);

            // if device is not closed
            if (device.State != DeviceState.Closed)
                // close the device
                device.Close();

            MessageBox.Show("Scan is finished.");
        }

    }
}

Send Feedback