Private VSTwain1 As New VintaSoftTwain()


''' <summary>
''' Scans images asynchronously.
''' </summary>
Private Sub ScanImages()
    ' open the device manager
    If Not VSTwain1.DeviceManager_Open() Then
        Console.WriteLine(VSTwain1.errorString)
        Exit Sub
    End If

    ' select device using standard device selection dialog
    VSTwain1.DeviceManager_ShowDefaultDeviceSelectionDialog()

    ' open the device
    If Not VSTwain1.Device_Open Then
        Console.WriteLine(VSTwain1.errorString)
        Exit Sub
    End If

    ' set units of measure to inches
    VSTwain1.Device_UnitOfMeasure = UNITOFMEASURE.UNITOFMEASURE_Inches
    ' get the image layout
    Dim left, top, right, bottom As Single
    VSTwain1.Device_GetImageLayout(left, top, right, bottom)

    ' subscribe to the device events
    AddHandler VSTwain1.DeviceImageAcquired, AddressOf VSTwain1_ImageAcquired
    AddHandler VSTwain1.DeviceScanCompleted, AddressOf VSTwain1_ScanCompleted
    AddHandler VSTwain1.DeviceScanFailed, AddressOf VSTwain1_ScanFailed
    AddHandler VSTwain1.DeviceScanCanceled, AddressOf VSTwain1_ScanCanceled

    ' acquire images asynchronously
    VSTwain1.Device_AcquireImage()
End Sub

Private Sub VSTwain1_ImageAcquired()
    ' get index of acquired image
    Dim imageIndex As Integer = VSTwain1.AcquiredImages_Count - 1

    ' save acquired image to TIFF file
    If Not VSTwain1.AcquiredImages_Save(imageIndex, "test.tif") Then
        Console.WriteLine(VSTwain1.errorString)
    End If
End Sub

Private Sub VSTwain1_ScanCompleted()
    Console.WriteLine("Scan is completed.")
End Sub

Private Sub VSTwain1_ScanFailed(errorString As String)
    Console.WriteLine(String.Format("Scan is failed: {0}.", errorString))
End Sub

Private Sub VSTwain1_ScanCanceled()
    Console.WriteLine("Scan is canceled.")
End Sub